Excel VBA: Nie można uzyskać dopasowania, błąd "Nie można uzyskać właściwości Match klasy WorksheetFunction"

Question

Z miłości do wszystkiego, co jest dobre, nie mogę sprawić, żeby to działało. Nadal dostaję powyższy błąd.

Mam tę tabelę i próbuję sprawdzić, czy kod pasuje do jej własnego pod-kodu gdzieś w drugiej kolumnie, ale jest to błąd. Twoja pomoc jest bardzo doceniana.

Sub testing() 

    Dim m1 As long 
    Dim myrange As Range 

    Set myrange = Worksheets("Sheet1").Range("B2:B23") 

    For e = 2 To 23 
     m1= Application.WorksheetFunction.Match(Cells(e, 1).Value, myrange, 0) 

     If m1 > 0 Then 
      Cells(e, 3).Value = "Yes" 
     Else 
      Cells(e, 3).Value = "No" 
     End If 
    Next e 

MsgBox "Complete!" 

End Sub 

Answer 1

użyć funkcji Application.Match co pozwala na lepszą zdolność do wychwytywania błędów. Podczas korzystania z WorksheetFunction.Match, gdy dopasowanie nie zostanie znalezione, zwraca błąd, który występuje.

If Not IsError(Application.Match(Cells(e, 1).Value, myrange, 0)) Then 
    'Do stuff when the match is found 
    Cells(e, 3).Value = "Yes" 
Else: 
    Cells(e, 3).Value = "No" 
End If 

Można też potencjalnie użyć CountIf funkcję:

If Application.WorksheetFunction.CountIf(myRange, Cells(e,1).Value) > 0 Then 
    Cells(e,3).Value = "Yes" 
Else: 
    Cells(e,3).Value = "No" 
End If 

Żadna z tych metod wymaga użycia zmiennej m1 można przypisać tej zmiennej w True części zestawienia If/Then, jeśli musisz zidentyfikować gdzie dopasowanie zostanie znalezione.

Answer 2

Podobnie jak w przypadku innej opcji, można to również zrobić, umieszczając poniższy wzór w komórce C2 i przeciągając go do C23.

=IF(COUNTIF($A$2:$A$23,B2)>=1,"YES","NO")